JacksonDunstan.com

package
{
	import flash.display.*;
	import flash.events.*;
	import flash.text.*;
	import flash.geom.*;
	import flash.ui.*;
	import flash.utils.*;
 
	[SWF(backgroundColor="0xEEEADB",frameRate="40",width="640",height="480")]
 
	/**
	*   A (hopefully) real world test of try/catch performance
	*   @author Jackson Dunstan
	*/
	public class TryCatchTester extends Sprite
	{
		/** If we should use a try/catch block during update */
		private var __useTryCatch:Boolean;
 
 		/** Last time we updated FPS */
		private var __lastFPSUpdateTime:uint;
 
		/** Last time we entered a frame */
		private var __lastFrameTime:uint;
 
		/** Count of frames since the last time we updated the FPS */
		private var __frameCount:uint;
 
		/** Framerate display */
		private var __framerate:TextField;
 
		/** Text field to show status */
		private var __status:TextField;
 
		/** Display of the results */
		private var __display:Bitmap;
 
		/** A bitmap to compose the image on before drawing it to the display */
		private var __backBuffer:BitmapData;
 
		/**
		*   Application entry point
		*/
		public function TryCatchTester()
		{
			// Setup stage
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
 
 			// Setup the display
 			var bmd:BitmapData = new BitmapData(2000, 2000, false, 0x00000000);
 			__display = new Bitmap(bmd);
 			addChild(__display);
 			__backBuffer = new BitmapData(2000, 2000, false, 0x00000000);
 
 			var format:TextFormat = new TextFormat();
			format.font = "_sans";
 
			// Setup framerate display
			__framerate = new TextField();
			__framerate.autoSize = TextFieldAutoSize.LEFT;
			__framerate.background = true;
			__framerate.backgroundColor = 0xEEEADB;
			__framerate.selectable = false;
			__framerate.text = "Gathering FPS data...";
			__framerate.setTextFormat(format);
			__framerate.defaultTextFormat = format;
			addChild(__framerate);
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			// Setup logger
			__status = new TextField();
			__status.y = __framerate.height;
			__status.autoSize = TextFieldAutoSize.LEFT;
			__status.background = true;
			__status.backgroundColor = 0xEEEADB;
			__status.selectable = false;
			__status.text = "Use try/catch block: " + __useTryCatch;
			__status.setTextFormat(format);
			__status.defaultTextFormat = format;
			addChild(__status);
 
 			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
		}
 
		/**
		*   Callback for when a frame is entered
		*   @param ev ENTER_FRAME event
		*/
		private function onEnterFrame(ev:Event): void
		{
			// Update frame rate counter
			__frameCount++;
			var now:int = getTimer();
			var dTime:int = now - __lastFrameTime;
			var elapsed:int = now - __lastFPSUpdateTime;
			if (elapsed > 1000)
			{
				var framerateValue:Number = 1000 / (elapsed / __frameCount);
				if (__framerate.visible)
				{
					__framerate.text = "FPS: " + framerateValue.toFixed(4);
				}
				__lastFPSUpdateTime = now;
				__frameCount = 0;
			}
			__lastFrameTime = now;
 
			// Do work, optionally in a try/catch block
			if (__useTryCatch)
			{
				updateTryCatch(dTime);
			}
			else
			{
				updateNoTryCatch(dTime);
			}
		}
 
		/**
		*   Update based on elapsed time with NO try/catch
		*   @param elapsed Number of milliseconds elapsed since the last update
		*/
		private function updateNoTryCatch(elapsed:int): void
		{
			var bmd:BitmapData = __backBuffer;
			for (var x:int = 0; x < 2000; ++x)
			{
				for (var y:int = 0; y < 2000; ++y)
				{
					bmd.setPixel32(x, y, x*y);
				}
			}
			__display.bitmapData.draw(bmd);
		}
 
		/**
		*   Update based on elapsed time WITH a try/catch
		*   @param elapsed Number of milliseconds elapsed since the last update
		*/
		private function updateTryCatch(elapsed:int): void
		{
			try
			{
				var bmd:BitmapData = __backBuffer;
				for (var x:int = 0; x < 2000; ++x)
				{
					for (var y:int = 0; y < 2000; ++y)
					{
						bmd.setPixel32(x, y, x*y);
					}
				}
				__display.bitmapData.draw(bmd);
			}
			catch (err:Error)
			{
			}
		}
 
		/**
		*   Callback for when a key is pressed anywhere on the stage
		*   @param ev KEY_DOWN event
		*/
		private function onKeyDown(ev:KeyboardEvent): void
		{
			if (ev.keyCode == Keyboard.SPACE)
			{
				__useTryCatch = !__useTryCatch;
				__status.text = "Use try/catch block: " + __useTryCatch;
			}
		}
	}
}