JacksonDunstan.com

package
{
	import flash.geom.Matrix;
	import flash.events.MouseEvent;
	import flash.text.TextFormat;
	import flash.geom.Rectangle;
	import flash.utils.getTimer;
	import flash.text.TextFieldAutoSize;
	import flash.display.StageScaleMode;
	import flash.display.StageAlign;
	import flash.text.TextField;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
 
	public class BitmapScaleRotFlash extends Sprite
	{
		[Embed(source="opaque.jpg")]
		private static const OPAQUE:Class;
 
		[Embed(source="alpha.png")]
		private static const ALPHA:Class;
 
		private var opaqueBMD:BitmapData = (new OPAQUE() as Bitmap).bitmapData;
		private var alphaBMD:BitmapData = (new ALPHA() as Bitmap).bitmapData;
		private var screenBMD:BitmapData;
		private var screenRect:Rectangle;
		private var drawMat:Matrix;
		private var time:TextField;
 
		public function BitmapScaleRotFlash()
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
 
			screenRect = new Rectangle(0, 0, stage.stageWidth, stage.stageHeight);
			screenBMD = new BitmapData(640, 480);
			addChild(new Bitmap(screenBMD));
 
			drawMat = new Matrix();
 
			makeButtons(
				"Alpha - Rotation", "Alpha - Scaling", "Alpha - Rotation & Scaling", null,
				"Opaque - Rotation", "Opaque - Scaling", "Opaque - Rotation & Scaling"
			);
 
			time = new TextField();
			time.text = "Time: 9999";
			time.autoSize = TextFieldAutoSize.LEFT;
			time.x = stage.stageWidth - time.width;
			time.y = stage.stageHeight - time.height;
			addChild(time);
		}
 
		private function makeButtons(...labels): Number
		{
			const PAD:Number = 5;
			var curX:Number = PAD;
			var curY:Number = stage.stageHeight - PAD;
			for each (var label:String in labels)
			{
				if (label == null)
				{
					curX = PAD;
					curY -= button.height + PAD;
					continue;
				}
 
				var tf:TextField = new TextField();
				tf.mouseEnabled = false;
				tf.selectable = false;
				tf.defaultTextFormat = new TextFormat("_sans");
				tf.autoSize = TextFieldAutoSize.LEFT;
				tf.text = label;
				tf.name = "lbl";
 
				var button:Sprite = new Sprite();
				button.buttonMode = true;
				button.graphics.beginFill(0xF5F5F5);
				button.graphics.drawRect(0, 0, tf.width+PAD, tf.height+PAD);
				button.graphics.endFill();
				button.graphics.lineStyle(1);
				button.graphics.drawRect(0, 0, tf.width+PAD, tf.height+PAD);
				button.addChild(tf);
				button.addEventListener(MouseEvent.CLICK, onButton);
				if (curX + button.width > stage.stageWidth - PAD)
				{
					curX = PAD;
					curY -= button.height + PAD;
				}
				button.x = curX;
				button.y = curY - button.height;
				addChild(button);
 
				curX += button.width + PAD;
			}
 
			return curY - button.height;
		}
 
		private function onButton(ev:MouseEvent): void
		{
			var mode:String = ev.target.getChildByName("lbl").text;
			switch (mode)
			{
				case "Opaque - Rotation":
					test(opaqueBMD, true, false);
					break;
				case "Opaque - Scaling":
					test(opaqueBMD, false, true);
					break;
				case "Opaque - Rotation & Scaling":
					test(opaqueBMD, true, true);
					break;
				case "Alpha - Rotation":
					test(alphaBMD, true, false);
					break;
				case "Alpha - Scaling":
					test(alphaBMD, false, true);
					break;
				case "Alpha - Rotation & Scaling":
					test(alphaBMD, true, true);
					break;
			}
		}
 
		private function test(bmd:BitmapData, rotation:Boolean, scaling:Boolean): void
		{
			var REPS:int = 10000;
			var maxX:int = screenRect.width - bmd.width;
			var maxY:int = screenRect.height - bmd.height;
			var beforeTime:int = getTimer();
			screenBMD.fillRect(screenRect, 0xffffffff);
			screenBMD.lock();
			for (var i:int = 0; i < REPS; ++i)
			{
				drawMat.a = drawMat.d = 1;
				drawMat.b = drawMat.c = 0;
 
				if (scaling)
				{
					drawMat.a = 1+Math.random();
					drawMat.d = 1+Math.random();
				}
 
				if (rotation)
				{
					drawMat.rotate(Math.random()*Math.PI*2);
				}
 
				drawMat.tx = Math.random()*maxX;
				drawMat.ty = Math.random()*maxY;
 
				screenBMD.draw(bmd, drawMat);
			}
			screenBMD.unlock();
			var afterTime:int = getTimer();
			time.text = "Time: " + (afterTime-beforeTime); 
		}
	}
}