JacksonDunstan.com

package
{
	import flash.utils.getTimer;
	import flash.display.Bitmap;
	import flash.display.LoaderInfo;
	import flash.display.Loader;
	import flash.net.URLRequest;
	import flash.events.Event;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLLoader;
	import flash.display.BitmapData;
	import flash.utils.ByteArray;
 
	public class Test
	{
		private static const NUM_BITMAPS:int = 10;
 
		private var bmdBytes:ByteArray;
		private var bmds:Vector.<BitmapData> = new Vector.<BitmapData>();
		private var url:String;
		private var label:String;
		private var callback:Function;
 
		public function Test(url:String, label:String)
		{
			this.url = url;
			this.label = label;
		}
 
		public function start(callback:Function): void
		{
			this.callback = callback;
 
			var loader:URLLoader = new URLLoader();
			loader.dataFormat = URLLoaderDataFormat.BINARY;
			loader.addEventListener(Event.COMPLETE, onBytesLoaded);
			loader.load(new URLRequest(url));
		}
 
		private function onBytesLoaded(ev:Event): void
		{
			bmdBytes = (ev.target as URLLoader).data;
			loadBitmap();
		}
 
		private function loadBitmap(): void
		{
			var loader:Loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoaded);
			loader.loadBytes(bmdBytes);
		}
 
		private function onLoaded(ev:Event): void
		{
			var bmd:BitmapData = ((ev.target as LoaderInfo).content as Bitmap).bitmapData;
			bmds.push(bmd);
			if (bmds.length < NUM_BITMAPS)
			{
				loadBitmap();
				return;
			}
 
			var beforeTime:int;
			var afterTime:int;
			var i:int;
			var decompressTime:int;
 
			// Check decompression time
			beforeTime = getTimer();
			for (i = 0; i < NUM_BITMAPS; ++i)
			{
				bmds[i].getPixel(0, 0);
			}
			afterTime = getTimer();
			decompressTime = afterTime - beforeTime;
 
			callback(label, decompressTime, bmdBytes.length);
		}
	}
}

package
{
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
 
	public class DecompressPerformance extends Sprite
	{
		private static const FILENAME:String = "Adobe_Flash_Professional_CS5_icon";
		private var logger:TextField;
		private var tests:Vector.<Test> = new <Test>[
			new Test(FILENAME + ".png", "PNG (ARGB)"),
			new Test(FILENAME + "_grey.png", "PNG (greyscale)"),
			new Test(FILENAME + "_indexed.png", "PNG (indexed)"),
			new Test(FILENAME + "_q1.jpg", "JPEG (q=1)"),
			new Test(FILENAME + "_q50.jpg", "JPEG (q=50)"),
			new Test(FILENAME + "_q100.jpg", "JPEG (q=100)"),
			new Test(FILENAME + "_q1.jxr", "JPEG-XR (q=1)"),
			new Test(FILENAME + "_q50.jxr", "JPEG-XR (q=50)"),
			new Test(FILENAME + "_q100.jxr", "JPEG-XR (q=100)")
		];
 
		public function DecompressPerformance()
		{
			logger = new TextField();
			logger.autoSize = TextFieldAutoSize.LEFT;
			logger.text = "Test,Decompress Time,File Size,Bytes/Sec\n";
			addChild(logger);
 
			startNextTest();
		}
 
		private function startNextTest(): void
		{
			if (tests.length == 0)
			{
				return;
			}
 
			tests.shift().start(onTestDone);
		}
 
		private function onTestDone(label:String, decompressTime:int, fileSize:uint): void
		{
			var rate:int = fileSize / (decompressTime/1000.0);
			logger.appendText(label + "," + decompressTime + "," + fileSize + "," + rate + "\n");
			startNextTest();
		}
	}
}