Comments on: Utility Functions For DisplayObjects

By: jackson

jackson — Wed, 17 Feb 2010 07:46:48 +0000

I don't think it's any faster or slower, just my habit from years of using the C++ STL where pre-incrementing an iterator is faster than post-incrementing. These days I just think it lends some visual balance to the line of code. :)

By: Denis

Denis — Wed, 17 Feb 2010 03:50:06 +0000

Hi Jakson,

Could you explain why did you use pre-increment in the getChildren function and not post-increment? Is it significant difference?

By: Jonny Reeves

Jonny Reeves — Wed, 10 Feb 2010 12:44:35 +0000

Simple but effective:

/**
 * Returns a Bitmap instance of the supplied DisplayObject.
 */
public static function createBitmap(source : DisplayObject, useSmoothing : Boolean = true) : Bitmap
{
    const bitmapData : BitmapData = new BitmapData(source.width, source.height, true, 0xffffff);
    bitmapData.draw(source);
 
    const bitmap : Bitmap = new Bitmap(bitmapData);
    bitmap.smoothing = useSmoothing;
 
    return bitmap;
}

By: jackson

jackson — Fri, 11 Dec 2009 17:30:58 +0000

getFullBounds is really interesting. I applied formatting and cleaned up some HTML safety stuff. Thanks for contributing!

By: Matt W

Matt W — Fri, 11 Dec 2009 16:01:46 +0000

/**
 * Determines the full bounds of the display object regardless of masking elements.
 * @param    displayObject    The display object to analyze.
 * @return    the display object dimensions.
 */
public static function getFullBounds( displayObject:DisplayObject ):Rectangle
{
    var bounds:Rectangle, transform:Transform, toGlobalMatrix:Matrix, currentMatrix:Matrix;
 
    transform = displayObject.transform;
    currentMatrix = transform.matrix;
    toGlobalMatrix = transform.concatenatedMatrix;
    toGlobalMatrix.invert();
    transform.matrix = toGlobalMatrix;
 
    bounds = transform.pixelBounds.clone();
 
    transform.matrix = currentMatrix;
 
    return bounds;
}
 
/**
 * Stops all timelines of the specified display object and its children.
 * @param    displayObject    The display object to loop through.
 */
public static function stopAllTimelines( displayObject:DisplayObjectContainer ):void
{
    var numChildren:int = displayObject.numChildren;
 
    for (var i:int = 0; i < numChildren; i++ )
    {
        var child:DisplayObject = displayObject.getChildAt( i );
 
        if ( child is DisplayObjectContainer ) 
        {
            if ( child is MovieClip ) 
            {
                MovieClip( child ).stop();
            }
 
            stopAllTimelines( child as DisplayObjectContainer );
        }
    }
}

By: jackson

jackson — Thu, 10 Dec 2009 17:48:31 +0000

I’ve added code formatting and cleaned up the HTML safety stuff that got applied. I can see some of these being very handy. Also, I really like your concise for loops over children:

for (var i:int = 0, len = obj.numChildren; i < len; ++i)
{
    // ...
}

Compared to a for-each over my getChildren it’s more efficient, but also more typing. Still, it’s nice to have options like these. Thanks for the contribution!

By: jackson

jackson — Thu, 10 Dec 2009 17:42:58 +0000

Thanks for the tip. I actually wrote wait while I was new to AS3 and didn't know that other DisplayObject derivatives could get the ENTER_FRAME event. It seems counter-intuitive to me, since they don't have frames. I've updated the article to use a Shape since it seems like the cheapest object that will dispatch the event. Lastly, thanks for your contribution!

By: Karl Knocking

Karl Knocking — Thu, 10 Dec 2009 11:32:11 +0000

I really like the for-loop in the isVisible Function. Althoug i think i never needed such a function. ;)

One suggestion: Wouldn’t it be better to use DisplayObject or EventDispatcher in the wait-function instead of MovieClip?

Here’s a function that I often use. It let’s you find the position of one MovieClip in the coordinate system of another one:

public static function relativePos(dO1:DisplayObject, dO2:DisplayObject):Point{
    var pos:Point = new Point(0,0);
    pos = dO1.localToGlobal(pos);
    pos = dO2.globalToLocal(pos);
    return pos;
}

By: vitaLee

vitaLee — Thu, 10 Dec 2009 08:29:51 +0000

public static function filterChildrenByProps(container:DisplayObjectContainer, props:Object):Array {
            var filteredChildren:Array = [];
            var child            :DisplayObject;
 
            for (var i:int = 0, l = container.numChildren; i < l; i++) {
                child = container.getChildAt(i);
                var isOK:Boolean = true;
                for (var prop:String in props) {
                    if (child[prop] != props[prop]){
                        isOK = false;
                        break;
                    }
                }
                if(isOK) filteredChildren.push(child);
            }
            return filteredChildren;
        }
 
 
 
public static function setProperties(children:Array, props:Object):void {
            var child:DisplayObject;
            for (var i:int = 0, l = children.length; i < l; i++) {
                child = children[i];
                for(var prop:String in props) {
                    child[prop] = props[prop];
                }
            }
        }
 
 
public static function sumProps(children:Array, prop:String):Number {
            var sum:Number = 0;
            for (var i:int = 0, l = children.length; i < l; i++) {
                sum += children[i][prop];
            }
            return sum;
        }
 
public static function originalWidth(obj:DisplayObject):Number {
            return obj.width / obj.scaleX;
        }
 
        public static function originalHeight(obj:DisplayObject):Number {
            return obj.height / obj.scaleY;
        }